程式名稱 : airtst2.zip (下載)

            CHIP    80152

PP0         EQU     080H
PP2         EQU     0A0H

DELTIM      EQU     30H
DELTIM_REG  EQU     31H

WATCHDOG    REG     PP2.7

SOL1        REG     P3.4        ;P3.4 電磁閥1
SOL2        REG     P3.5        ;P3.5 電磁閥2  
RELAY4      REG     P3.7        ;工作中指示

START       REG     PP0.0    ;  P0.0 RUN BUTTON
LS1         REG     PP0.1    ;  P0.1 LS1
LS2         REG     PP0.2    ;  P0.2 LS2

;============================================================================
        ORG     0H  
;============================================================================
AGAIN:
        CPL     WATCHDOG
        MOV     P1,#11110000B
        MOV     P0,#11111111B
        CALL    DEL
;============================================================================
        MOV     P1,#11110000B
WORK:   
        CPL     WATCHDOG        ;啟動  
        JNB     START,WORK
        CALL    DEL1
        JNB     START,WORK
WORK10:
        CPL     WATCHDOG
        JB      START,WORK10
        CALL    DEL1

        SETB    SOL2
        CLR     SOL1            ;電磁閥ON
        CLR     RELAY4
WORK20:                         ;CHECK LS1
        CPL     WATCHDOG
        JNB     LS1,WORK20
        CALL    DEL1
        JNB     LS1,WORK20
        
        SETB    SOL1            ;電磁閥OFF
        CLR     SOL2
  
WORK30:                         ;CHECK LS2
        CPL     WATCHDOG
        JNB     LS2,WORK30
        CALL    DEL1
        JNB     LS2,WORK30
        
        SETB    SOL2
        SETB    RELAY4

        JMP     WORK
;============================================================================
DEL1:
        MOV     R3,#020H
DEL1A:
        MOV     R4,#0FFH
DEL1B:
        CPL     WATCHDOG
        DJNZ    R4,DEL1B
        DJNZ    R3,DEL1A
        RET
;============================================================================
DEL:
        MOV     R3,#0FFH
DELA:
        MOV     R4,#0FFH
DELB:
        CPL     WATCHDOG
        DJNZ    R4,DELB
        DJNZ    R3,DELA
        RET